Remote Dual Boot Switch (UEFI)

Date: 05/07/2026

Description

The objective is to configure a dual-boot system where each operating system remains the default after rebooting into itself, while still allowing remote switching between Windows and Ubuntu.

Expected behavior

Windows → Reboot → Windows
Ubuntu → Reboot → Ubuntu
Windows → Ubuntu (remote switch)
Ubuntu → Windows (remote switch)

The goal is to switch operating systems remotely (RDP/VNC/SSH) without requiring physical access to the UEFI boot menu.

Installation

Install Windows 11 (use the bypass script if needed).
Install Ubuntu.
After Ubuntu installation, the system boots into Ubuntu.

At this stage it is already possible to boot Windows manually from the UEFI boot menu, but this is not the objective.

The objective is to switch operating systems remotely.

Ubuntu → Windows

Status

✅ Working on new installation
✅ Working on existing installation

Question

How can we boot Windows automatically from Ubuntu?

Solution

Linux script:

#!/bin/bash
echo "Go to Windows"
sudo efibootmgr -c \
-d /dev/nvme0n1 \
-p 1 \
-L "Windows Direct" \
-l '\EFI\Microsoft\Boot\bootmgfw.efi'
sudo reboot

Or use this 2_nd script :

#Script for Linux_2 : ==> this is safest and better
#--------------------------------------------
#!/bin/bash
sudo efibootmgr # ==> detect windows number from here
sleep 4
sudo efibootmgr -o 0005
reboot
#---------------

Result

The script creates a UEFI firmware entry pointing directly to Windows Boot Manager and immediately reboots.

After reboot:

Ubuntu → Windows ✅
Windows remains the default operating system for future reboots.

Windows → Ubuntu

Initial Questions

Now our system always boots into Windows.

This is great, but:

How do we boot back into Ubuntu from Windows?
We need to find the firmware GUID of the installed Ubuntu boot entry.
How can we automatically identify the correct Ubuntu GUID?
Once we have the GUID, how do we configure Windows to boot Ubuntu?

Step 1 – Find the Ubuntu GUID

Run:

bcdedit /enum firmware

Locate the firmware entry:

description             ubuntu

Example:

Firmware Application (101fffff)
-------------------------------
identifier              {27ed8440-a923-11f0-9bb3-000c296a303d}
device                  partition=\Device\HarddiskVolume1
path                    \EFI\ubuntu\shimx64.efi
description             ubuntu

Copy the identifier (GUID).

Step 2 – Configure Windows to Boot Ubuntu

@echo off
::DK

:: find Ubuntu GUI and set as acticve
setlocal EnableDelayedExpansion

set "UBUNTU_GUID="

for /f "delims=" %%L in ('bcdedit /enum firmware') do (
set "L=%%L"

echo(!L! | findstr /b /c:"identifier" >nul
if not errorlevel 1 (
for %%A in (!L!) do set "UBUNTU_GUID=%%A"
)

echo(!L! | findstr /b /c:"description" >nul
if not errorlevel 1 (
echo(!L! | findstr /i /c:"ubuntu" >nul
if not errorlevel 1 (
echo Ubuntu GUID: !UBUNTU_GUID!
goto :next
)
)
)

:next
:: --------------------------------------
:: Set Ubuntu as default boot via BCD
:: --------------------------------------
:: Ubuntu firmware entry GUID from backup
set UBUNTU_GUID=!UBUNTU_GUID!

:: Windows Boot Manager GUID (fallback)
set WIN_GUID={bootmgr}

:: Set Ubuntu as default firmware boot
bcdedit /set {fwbootmgr} default %UBUNTU_GUID%

:: Set display order: Ubuntu first, Windows second
bcdedit /set {fwbootmgr} displayorder %UBUNTU_GUID% %WIN_GUID%

:: Optional: set boot menu timeout
bcdedit /timeout 2

:: --------------------------------------
:: Confirmation before restart
:: --------------------------------------

set "VBS=%TEMP%\confirm_restart.vbs"

> "%VBS%" echo Set WshShell = CreateObject("WScript.Shell")
>>"%VBS%" echo answer = MsgBox("Ubuntu has been configured as the next boot option." ^& vbCrLf ^& vbCrLf ^& "Restart the computer now?", vbQuestion + vbYesNo + vbDefaultButton1, "Cherry")
>>"%VBS%" echo If answer = vbYes Then
>>"%VBS%" echo WshShell.Run "%SystemRoot%\System32\shutdown.exe /r /t 0", 0, False
>>"%VBS%" echo End If
cscript //nologo "%VBS%"
del "%VBS%"
exit /b

Result

Success!

After reboot:

Windows → Ubuntu ✅
Ubuntu remains the default operating system until another script changes the firmware boot configuration.

Final Result

Current OS	Action	Result
Windows	Normal reboot	Windows
Ubuntu	Normal reboot	Ubuntu
Windows	Run switch script	Ubuntu
Ubuntu	Run switch script	Windows

The system can now switch operating systems in both directions without requiring access to the UEFI boot menu, making it suitable for remote administration.